Jak stáhnout starší verze Windows 10 pomocí nástroje Media Creation Tool
S každou novou aktualizací Windows 10 se aktualizuje i nástroj Media Creation Tool. Ten umožňuje stahování instalací Windows 10. Nové verze nástroje vždy nabízejí aktuální, nejnovější verzi systému. Pokud tedy potřebujete stáhnout a nainstalovat starší build, oficiální nástroj Media Creation Tool od Microsoftu vám nepomůže. Nicméně, ISO soubory pro starší verze stále existují a pomocí jednoduchého BAT skriptu si můžete stáhnout libovolnou verzi Windows 10 přes tento nástroj.
SPOILER: Na konci článku najdete video s návodem.
Získejte libovolnou verzi Windows 10
Tento BAT soubor vytvořil uživatel na Redditu s přezdívkou aveyo. Skript si můžete stáhnout z jeho Pastebin linku, pro jistotu ho ale poskytneme i přímo zde, kdyby odkaz přestal fungovat.
Otevřete Poznámkový blok (Notepad) a vložte do něj následující kód. Uložte soubor s příponou .bat.
@echo off &title MediaCreationTool.bat by AveYo
:: Univerzální obal pro všechny "RedStone" verze: 1607, 1703, 1709, 1803 a 1809
:: Využívá pouze originální soubory hostované Microsoftem pro aktuální i starší verze MCT
:: Skvělá podpora vytváření business kanálu (Enterprise) s vlastním jazykem, x86, x64 nebo AIO!
:: V případě potřeby přidejte / odeberte parametry spuštění - přednastaveno pro nejméně problémů při aktualizacích
set "OPTIONS=/Telemetry Disable /DynamicUpdate Disable /MigrateDrivers all /ResizeRecoveryPartition disable /ShowOOBE none"
:: Odkomentujte pro zobrazení živého logu mct konzole pro ladění
rem set "OPTIONS=%OPTIONS% /Console"
:: Odkomentujte pro přeskočení výběru z gui a tvrdé nastavení cílové verze: 1=1607, 2=1703, 3=1709, 4=1803, 5=1809
rem set/a MCT_VERSION=5
:: Dostupné MCT verze
set versions= 1607 [ RedStone 1 ], 1703 [ RedStone 2 ], 1709 [ RedStone 3 ], 1803 [ RedStone 4 ], 1809 [ RedStone 5 ]
:: Zobrazení dialogového okna gui %1:title %2:header %3:choices %4:output_variable
if not defined MCT_VERSION call :choice "MediaCreationTool.bat by AveYo" "Vyberte verzi Windows 10" "%versions%" MCT_VERSION
if not defined MCT_VERSION echo Nebyla vybrána žádná MCT_VERSION, ukončuji.. & timeout /t 5 & exit/b
goto version%MCT_VERSION%
:version1 1607 [RS1]
set "V=1607"
set "D=20170116"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod/Products_20170116.cab"
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Verze %V% %D% vybrána!
goto process
:version2 1703 [RS2]
set "V=1703"
set "D=20170317"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://download.microsoft.com/download/9/5/4/954415FD-D9D7-4E1F-8161-41B3A4E03D5E/products_20170317.cab"
set "MCT=https://download.microsoft.com/download/1/C/4/1C41BC6B-F8AB-403B-B04E-C96ED6047488/MediaCreationTool.exe"
:: 1703 MCT je také bugnuté, takže použijte 1607 místo toho
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Verze %V% %D% vybrána!
goto process
:version3 1709 [RS3]
set "V=1709"
set "D=20180105"
set "EULA="
set "CAB=https://download.microsoft.com/download/3/2/3/323D0F94-95D2-47DE-BB83-1D4AC3331190/products_20180105.cab"
set "MCT=https://download.microsoft.com/download/A/B/E/ABEE70FE-7DE8-472A-8893-5F69947DE0B1/MediaCreationTool.exe"
echo Verze %V% %D% vybrána!
goto process
:version4 1803 [RS4]
set "V=1803"
set "D=20180420"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/2/6/626729CF-8C1C-43DF-8C9C-AD2FD56948C3/products_20180420.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1803.exe"
echo Verze %V% %D% vybrána!
goto process
:version5 1809 [RS5]
set "V=1809"
set "D=20180924"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/F/B/6FB97F08-E010-48A4-A9DC-18FCA920CEB4/products_20180924.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1809.exe"
echo Verze %V% %D% vybrána!
goto process
:process
echo.
echo Upozornění: MCT závisí na službě BITS! Pokud se vyskytnou nějaké problémy, spusťte skript jako správce..
bitsadmin.exe /reset /allusers 2>nul
net stop bits /y 2>nul
net start bits /y 2>nul
:: úklid - může zahrnovat i dočasné soubory, ale nedoporučuje se, protože nemůžete pokračovat přes C:$Windows.~WSSourcessetuphost
pushd "%~dp0"
del /f /q products.* 2>nul &rem rd /s/q C:$Windows.~WS 2>nul & rd /s/q C:$WINDOWS.~BT 2>nul
:: stáhnutí MCT
set "WEBCLIENT=[Net.ServicePointManager]::SecurityProtocol="tls12,tls11,tls";(new-object System.Net.WebClient)"
if not exist MediaCreationTool%V%.exe powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%MCT%','MediaCreationTool%V%.exe');"
if not exist MediaCreationTool%V%.exe color 0c & echo Chyba! chybí MediaCreationTool%V%.exe & pause & exit /b
:: stáhnutí CAB
if not exist products_%D%.cab powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%CAB%','products_%D%.cab');"
if not exist products_%D%.cab color 0c & echo Chyba! chybí products_%D%.cab & pause & exit /b
:: rozbalení CAB
expand.exe -R products_%D%.cab -F:* . >nul 2>nul
if not exist products.xml color 0c & echo Chyba! špatný nebo chybějící products_%D%.cab & pause & exit /b
:: patch XML pro povolení výběru business kanálu (Enterprise) a drobná kosmetická úprava
set "READ_XML=$f=[System.IO.File]::ReadAllText('products.xml')"
set "WRITE_XML=[System.IO.File]::WriteAllText('products.xml', $f)"
set "r1= $f=$f.Replace('IsRetailOnly>True<','IsRetailOnly>False<')"
set "r2=.Replace('%%ENTERPRISE','Windows 10 Enterprise')"
:: oprava starých EULA odkazů, které způsobují problémy s MCT v 1607 a 1703
if not defined EULA (set "r3=") else set "r3=.Replace('%EULA%','%EULA_FIX%')"
powershell -c "%READ_XML%; %r1%%r2%%r3%; %WRITE_XML%;"
:: zabalení XML do CAB
start "" /wait makecab products.xml products.cab
:: konečně spuštění MCT s lokální konfigurací a volitelnými parametry
start "" MediaCreationTool%V%.exe /Selfhost %OPTIONS%
exit/b
:: utility
::------------------------------------------------------------------------------------------------------------------------------
:choice %1:title %2:header %3:choices %4:output_variable [GUI radioboxes dialog snippet by AveYo] uvolněno pod MIT licencí
setlocal &set "parameters=$title="%~1"; $header="%~2"; $choices="%~3"; $global:c="";"
set "s1=[void][System.Reflection.Assembly]::LoadWithPartialName('System.Windows.Forms');$f=New-Object System.Windows.Forms.Form"
set "s2=;$f.Text=$title; $f.Forecolor="Snow"; $f.BackColor=0xff180052; $f.StartPosition='CenterScreen'; $f.AutoSize=$true;"
set "s3=$g=New-Object System.Windows.Forms.GroupBox; $g.Location='40,10'; $g.Margin='0,0,40,0'; $g.MinimumSize="280,100";"
set "s4=$g.AutoSize=$true; $g.text=$header; $f.Controls.Add($g);"
set "s5=$i=1; foreach($l in $choices.split(',')){ $r=New-Object System.Windows.Forms.RadioButton; $r.Location='20,'+(30*$i);"
set "s6=$r.Name=$i;$r.Text=$l;$r.AutoSize=$true;$r.add_Click({$global:c=$this.Name}); $g.Controls.Add($r); $r.Checked=1; $i++};"
set "s7=$j=1;foreach($t in @('OK','Exit')){$b=New-Object System.Windows.Forms.Button;$b.Location=''+(120*($j-1)+80)+','+40*$i;"
set "s8=$b.Name="b"+$j; $b.Text=$t; $b.DialogResult=$j; if ($j -eq 1){$f.AcceptButton=$b}; $f.Controls.Add($b); $j++};"
set "s9=$f.Add_Shown({$f.Activate()}); $ret=$f.ShowDialog(); if ($ret -eq 2){$global:c=""}; write-host $global:c"
for /l %%# in (1,1,9) do call set "ps_Choice=%%ps_Choice%%%%s%%#:"="%%"
for /f "usebackq tokens=* delims=" %%# in (`powershell -noprofile -c "%parameters% %ps_Choice%"`) do set "output_var=%%#"
endlocal & set "%~4=%output_var%" & exit/b
::------------------------------------------------------------------------------------------------------------------------------
Spusťte tento BAT soubor s administrátorskými právy. Objeví se okno příkazového řádku, následované dalším oknem, kde vyberete, kterou verzi Windows 10 chcete stáhnout. Můžete si vybrat finální sestavení Redstone 1 – 5.
Po výběru verze se nástroj pro tvorbu médií stáhne do stejné složky, kam jste uložili BAT soubor. Nyní můžete nástroj spustit a použít ho pro stažení vybrané verze Windows 10. Nástroj vám umožní aktualizovat stávající instalaci, nebo vytvořit bootovací USB disk.
Všechny soubory se stahují přímo od Microsoftu. Tento BAT soubor pouze pomáhá najít správné soubory a spustit stahování. Nespravuje a neupravuje žádné soubory, které Microsoft sám zpřístupnil.